@echo off
title Ajer Fjernsupport
echo(
echo   ==========================================
echo     Ajer Fjernsupport - opsaetter forbindelse
echo   ==========================================
echo(
set "URL=https://vps.ajer.dk/dl/rustdesk"
set "DEST=%LOCALAPPDATA%\AjerFjernsupport"
if not exist "%DEST%" mkdir "%DEST%"

rem Hent den officielle (signerede) RustDesk
echo   Henter RustDesk... (foerste gang tager lidt tid)
where curl >nul 2>&1
if %errorlevel%==0 (
  curl -L -# -o "%DEST%\rustdesk.exe" "%URL%"
) else (
  powershell -NoProfile -Command "Invoke-WebRequest -Uri $env:URL -OutFile ($env:DEST + \"\rustdesk.exe\")"
)

if not exist "%DEST%\rustdesk.exe" (
  echo   FEJL: kunne ikke hente RustDesk. Tjek internetforbindelsen.
  pause
  exit /b 1
)

rem Luk evt. koerende RustDesk saa config laeses paa ny
taskkill /f /im rustdesk.exe >nul 2>&1
timeout /t 1 /nobreak >nul

rem Skriv forudkonfigureret server + key
set "RDCFG=%APPDATA%\RustDesk\config"
if not exist "%RDCFG%" mkdir "%RDCFG%"
(
echo rendezvous_server = 'vps.ajer.dk:21116'
echo nat_type = 1
echo serial = 0
echo(
echo [options]
echo key = 'K1uKyMA8jL0MXCz3ngK9EnRPz6gWBBe3NmUjclaC5ng='
echo custom-rendezvous-server = 'vps.ajer.dk'
echo relay-server = 'vps.ajer.dk'
) > "%RDCFG%\RustDesk2.toml"

echo   Klar - starter RustDesk...
start "" "%DEST%\rustdesk.exe"
exit